投稿日: 投稿者: ともの

電源周波数の変動を測ってみた

最近の寒波で電力供給の危機が叫ばれています。原子力発電所が震災以来（ほぼ？）停止していて、CO2の対策として石炭火力や石油での火力もだいぶ止まっているような話を聞きます。そこへ来て、大雪によってソーラーパネルに雪が積もって発電できないのですから当たり前といえば当たり前です。

電力供給が厳しくなると発電所から見た負荷が重くなるので、電源周波数の変動として見えてくるはずです。そこで、電源周波数の変動を見てみよう、ということになります。

電源周波数の取り出し

ちゃんと見ようと思うと、どうしても商用電源へのアクセスが必要で感電防止とかを考えると大がかりになりがちですが、今回は100円ショップで売っているニッケル水素電池の充電器を使うことにしました。100円ショップで入手したものは、以前分解したときに（電池を入れない状態では）電池のマイナス端子に内部のトランスの端子がそのまま出ていることに気づきました。そこで、ここから商用電源の信号を取ることにします。(注意： 感電の恐れが大きい部分に触れることなく取り出せますが、この充電器の本来の使い方とは異なりますので、まねする場合には十分注意して行うとともに、自己責任で行ってください。似た形状で回路構成が違うものもあるかもしれませんし。）

このようにオシロスコープのプローブを2つの電池のマイナス端子に接続して波形観測すると、Peak-to-Peakで12Vくらいあることがわかります。ここにフォトカプラを入れて信号を取り出すことを考えます。

手持ちのフォトカプラPC817のデータシートを見ると、以下の特性を持っています。

フォトカプラの内蔵LEDにはIFは5mAも流してやれば良さそうです。VF=1.2V程度なので、ピーク時の6Vの際に10mA程度をターゲットに470Ωをつけてやることにします。抵抗には10mA程度流れるときに５Vの電圧がかかるので、50mWの消費電力・・・と思ったけど直流ではないので平均はもっと少ないですが、1/6Wのものを使うことにしました。あとはフォトカプラの内蔵LEDと逆向きに適当なLEDをつけておきます。これは何でもよく、AC電圧が逆相の際にフォトカプラの内蔵LEDに逆電圧がかかるのを防止するためです。
フォトカプラのフォトトランジスタ側の負荷抵抗は50Hzや60Hzでは周波数特性もへったくれもないので、IC=0.5mAも流れていれば十分ですから4.7kΩとしました。（よく考えたら、この抵抗は無しでIO8の内蔵プルアップを有効にするだけで十分かもしれない）

回路はこんな感じ。左のAC信号源の部分がニッケル水素充電器の２つのマイナス端子。真ん中のダイオードはLEDでフォトカプラの保護用。

ブレッドボード上に組んで波形を観測してみました。

右側のボードは秋月のAE-ATmega328ボードがボードのみで売られていた時代に組んだものです。ATmega328を載せてブートローダを書き込んだのだと思います。クリスタルは16MHzのものが載せてあって、Arduino Pro互換として動作していると思います。フォトカプラの出力はIO8へ接続しています。ATmega328のTCC1のカウント値をキャプチャする機能の入力信号ICP1として使用するためです。

上が充電器の２つの端子の電圧で、下がArduino互換ボードへの信号です。狙ったとおりの信号が得られています。

周期の計測

これをATmega328で周波数を計測します。TCC1の16ビットタイマをCPUのクロックを8分周したもの（つまり２MHｚ＝0.5uS）でフリーランさせて、インプットキャプチャ機能でICP1信号（IO8）の下がりエッジでその瞬間の値をICR1レジスタに取得します。取得したら割り込みでただちにICR1レジスタの値を読み出して保存します。実際には１秒周期で平均周波数を求めてホストに送信するので、割り込み内ではlongの変数に積算するとともに、積算回数をカウントします。また、よりデータを取る場合にはその１秒間での最短周期や最長周期も取得しておきます。

メインのループ側では１秒毎に積算値から平均の周期もしくは周波数を求めてシリアルでホストに送信します。それをArduino IDEのシリアルプロッタの機能でグラフ化するとこんな感じになります。

縦軸は周波数で、単位は1/1000Hzです。50000が50Hzぴったりということになります。このグラフの例では縦軸は49.92Hzから50.16Hzまでが表示されていて、電源の周波数は49.94Hzくらいから50.1Hzくらいまで変動しているということがわかります。右側はサンプル数ですが、データ送信は1秒間に1回なので、過去500秒間の電源周波数変動が見えます。

これをブレッドボードではなくて、ユニバーサル基板で組んでみました。

Arduino用のユニバーサル基板もあったのですが、回路規模が小さいのでより小さなユニバーサル基板で組んでみました。この範囲には5Vがないので、IO12をH出力してフォトカプラの内蔵フォトトランジスタの負荷抵抗の電源端子として使用することにしました。（注：実際には、IO8の内蔵プルアップを有効にするだけでも十分そうです。頑張れば更に小さいユニバーサル基板でも入ったかも。）

さらにソフトを修正して、1秒間の間の最短周期と最大周期も送信するようにしたところ、以下のような感じになりました。

理由はきちんと確認していませんが、1秒間の中での周波数変動が大きい時間と小さい時間があるようです。おそらくはインバータ機器などが動作している／していない期間なのでしょう。

ソフトウェア

平均のみをホストに送信する場合

ソースを表示
印刷SyntaxHighlighterについて
1#define TCCCLK 2000000    // CPUクロックを8分周した値。
2                          // Pro Miniなど8MHzで動作している製品の場合は 1000000 にする
3#define ICP1 8  // ICP1の端子を定義
4#define PWR  12 // フォトカプラの負荷抵抗に電源を供給するための端子
5 
6// 周期測定ののための変数
7volatile uint16_t NumV;
8volatile uint32_t SumV;
9volatile uint16_t CapV;
10volatile uint16_t PreCap,NowCap;
11 
12// 1秒間の最大最小平均を格納するための変数
13uint16_t tNumV;
14float tAveV;
15uint32_t tSumV;
16 
17unsigned long current_time;
18 
19// 割り込みハンドラ
20ISR(TIMER1_CAPT_vect) {
21  TIFR1 |= (1<<ICF1);
22  NowCap = ICR1;
23  CapV = NowCap - PreCap;       // 差分を求めて周期を算出
24  PreCap = NowCap;
25  SumV += CapV;
26  NumV++;
27}
28 
29void setup()
30{
31  Serial.begin(38400);
32  pinMode(LED_BUILTIN, OUTPUT);
33   
34  // TCC1でICP1信号（PB0端子=IO8）の周期を計測する
35  TCCR1A = 0; //initialize Timer1
36  TCCR1B = 0;
37  TCNT1 = 0;
38   
39  // 4.7kΩなしで端子の内蔵プルアップで済ます場合
40  //  pinMode(ICP1, INPUT_PULLUP);  //ICP1の端子をプルアップなしの入力に設定する
41  //  pinMode(PWR,  INPUT);
42 
43  // 4.7kΩのプルアップありでこれをIO12から供給する場合
44  pinMode(ICP1, INPUT);  //ICP1の端子をプルアップなしの入力に設定する
45  pinMode(PWR,  OUTPUT);
46  digitalWrite(PWR, HIGH);
47 
48  TCCR1B =  0x02;   // 16MHzを8分周
49  TIMSK1 |= (1 << ICIE1); // キャプチャ割り込み許可
50  current_time = millis();
51}
52 
53#define FREQ  // 計測を周波数で行う場合
54 
55void loop()
56{
57  static uint8_t skp = 3;   // 最初の何回かはデータを捨てる
58   
59  if (millis() - current_time >= 1000)
60  {
61    // 割り込みで更新している変数をコピー＆初期化する
62    noInterrupts(); //割り込み停止
63    tSumV = SumV; tNumV = NumV;
64    SumV = 0; NumV = 0;
65    interrupts();   //割り込み再開
66    tAveV = (float)tSumV / (float)tNumV;
67     
68    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
69    current_time = millis();
70 
71    // PCに送信
72    if(skp == 0){
73      #ifdef FREQ
74      Serial.println((double)TCCCLK/(double)tAveV*1000.);
75      #else
76      Serial.println(tAveV/2);  // これで単位がusになる
77      #endif
78    } else {
79      skp--;
80    }
81  }
82}

１秒間の中の最大/最小も送信する場合

ソースを表示
印刷SyntaxHighlighterについて
1#define TCCCLK 2000000    // CPUクロックを8分周した値。
2                          // Pro Miniなど8MHzで動作している製品の場合は 1000000 にする
3#define ICP1 8  // ICP1の端子を定義
4#define PWR  12 // フォトカプラの負荷抵抗に電源を供給するための端子
5 
6// 周期測定ののための変数
7volatile uint16_t MaxV,MinV,NumV;
8volatile uint32_t SumV;
9volatile uint16_t CapV;
10volatile uint16_t PreCap,NowCap;
11 
12// 1秒間の最大最小平均を格納するための変数
13uint16_t tMaxV,tMinV,tNumV;
14float tAveV;
15uint32_t tSumV;
16 
17unsigned long current_time;
18 
19// 割り込みハンドラ
20ISR(TIMER1_CAPT_vect) {
21  TIFR1 |= (1<<ICF1);
22  NowCap = ICR1;
23  CapV = NowCap - PreCap;       // 差分を求めて周期を算出
24  PreCap = NowCap;
25  if(CapV > MaxV) MaxV = CapV;
26  if(CapV < MinV) MinV = CapV;
27  SumV += CapV;
28  NumV++;
29}
30 
31void setup()
32{
33  Serial.begin(38400);
34  pinMode(LED_BUILTIN, OUTPUT);
35   
36  // TCC1でICP1信号（PB0端子=IO8）の周期を計測する
37  TCCR1A = 0; //initialize Timer1
38  TCCR1B = 0;
39  TCNT1 = 0;
40   
41  // 4.7kΩなしで端子の内蔵プルアップで済ます場合
42  //  pinMode(ICP1, INPUT_PULLUP);  //ICP1の端子をプルアップなしの入力に設定する
43  //  pinMode(PWR,  INPUT);
44 
45  // 4.7kΩのプルアップありでこれをIO12から供給する場合
46  pinMode(ICP1, INPUT);  //ICP1の端子をプルアップなしの入力に設定する
47  pinMode(PWR,  OUTPUT);
48  digitalWrite(PWR, HIGH);
49 
50  TCCR1B =  0x02;   // 16MHzを8分周
51  TIMSK1 |= (1 << ICIE1); // キャプチャ割り込み許可
52  current_time = millis();
53}
54 
55#define FREQ  // 計測を周波数で行う場合
56 
57void loop()
58{
59  static uint8_t skp = 3;   // 最初の何回かはデータを捨てる
60   
61  if (millis() - current_time >= 1000)
62  {
63    // 割り込みで更新している変数をコピー＆初期化する
64    noInterrupts(); //割り込み停止
65    tMaxV = MaxV; tMinV = MinV; tSumV = SumV; tNumV = NumV;
66    MaxV = 0; MinV = 65535; SumV = 0; NumV = 0;
67    interrupts();   //割り込み再開
68    tAveV = (float)tSumV / (float)tNumV;
69     
70    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
71    current_time = millis();
72 
73    // PCに送信
74    if(skp == 0){
75      #ifdef FREQ
76      Serial.print((double)TCCCLK/(double)tMaxV*1000.);
77      Serial.print(",");
78      Serial.print((double)TCCCLK/(double)tMinV*1000.);
79      Serial.print(",");
80      Serial.println((double)TCCCLK/(double)tAveV*1000.);
81      #else
82      Serial.print(tMaxV/2);
83      Serial.print(",");
84      Serial.print(tMinV/2);
85      Serial.print(",");
86      Serial.println(tAveV/2);  // これで単位がusになる
87      #endif
88    } else {
89      skp--;
90    }
91  }
92}

おまけ

実は、AC電源から信号を取ってこなくてもAC電源の周波数変動は大雑把には計測できます。（バッテリで動作しているノートPCの場合は無理かも）
ICP1端子に適当なケーブルをつないで、ICP1端子をプルアップなしの入力端子にしてやると、周りとの静電誘導にて電源周波数のノイズが回り込みます。これで一応電源周波数のモニターができます。
ただし、外部からのノイズに非常に弱いと思われますし、静電気などで破壊されるリスクも増えると思います。

ソースを表示
印刷SyntaxHighlighterについて
1#define TCCCLK 2000000    // CPUクロックを8分周した値。
2                          // Pro Miniなど8MHzで動作している製品の場合は 1000000 にする
3#define ICP1 8  // ICP1の端子を定義
4 
5// 周期測定ののための変数
6volatile uint16_t NumV;
7volatile uint32_t SumV;
8volatile uint16_t CapV;
9volatile uint16_t PreCap,NowCap;
10 
11// 1秒間の最大最小平均を格納するための変数
12uint16_t tNumV;
13float tAveV;
14uint32_t tSumV;
15 
16unsigned long current_time;
17 
18// 割り込みハンドラ
19ISR(TIMER1_CAPT_vect) {
20  TIFR1 |= (1<<ICF1);
21  NowCap = ICR1;
22  CapV = NowCap - PreCap;       // 差分を求めて周期を算出
23  PreCap = NowCap;
24  SumV += CapV;
25  NumV++;
26}
27 
28void setup()
29{
30  Serial.begin(38400);
31  pinMode(LED_BUILTIN, OUTPUT);
32   
33  // TCC1でICP1信号（PB0端子=IO8）の周期を計測する
34  TCCR1A = 0; //initialize Timer1
35  TCCR1B = 0;
36  TCNT1 = 0;
37   
38  pinMode(ICP1, INPUT);  //ICP1の端子をプルアップなしの入力に設定する
39 
40  TCCR1B =  0x02;   // 16MHzを8分周
41  TIMSK1 |= (1 << ICIE1); // キャプチャ割り込み許可
42  current_time = millis();
43}
44 
45#define FREQ  // 計測を周波数で行う場合
46 
47void loop()
48{
49  static uint8_t skp = 3;   // 最初の何回かはデータを捨てる
50   
51  if (millis() - current_time >= 1000)
52  {
53    // 割り込みで更新している変数をコピー＆初期化する
54    noInterrupts(); //割り込み停止
55    tSumV = SumV; tNumV = NumV;
56    SumV = 0; NumV = 0;
57    interrupts();   //割り込み再開
58    tAveV = (float)tSumV / (float)tNumV;
59     
60    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
61    current_time = millis();
62 
63    // PCに送信
64    if(skp == 0){
65      #ifdef FREQ
66      Serial.println((double)TCCCLK/(double)tAveV*1000.);
67      #else
68      Serial.println(tAveV/2);  // これで単位がusになる
69      #endif
70    } else {
71      skp--;
72    }
73  }
74}

“電源周波数の変動を測ってみた” への2件の返信

  1. 周波数観測サイトのＷＥＢ側のプログラムの解説記事を作っていただけないでしょうか？？

    返信

コメントを残す

メールアドレスが公開されることはありません。 ※ が付いている欄は必須項目です

日本語が含まれない投稿は無視されますのでご注意ください。（スパム対策）